Leonardo the Inventor/Leonardo The Inventor (93026)(Broderbund)(Riverdeep)(2004).iso/LEOWINMV/DATABASE.DIR/00086_Script_HYPERTEXT LINKING

Text File | 1996-03-28 | 8KB | 232 lines

-- --------------------------------------------------------
-- Handler checkIfClickedHyperLink checks if the user
-- clicked on a hypertext.

on checkIfClickedHyperLink
  global textSprite, currentTextCast, hypertextWords

  set currentTextCast = the castNum of sprite textSprite

  set wordNumber = the mouseWord
  set clickedword = word wordNumber of field currentTextCast

  set linkType = getHyperLinkType(wordNumber)

  if (linkType <> -1) then
    processHyperLink(wordNumber, linkType)
  end if
end

-- --------------------------------------------------------
-- Handler getHyperLinkType returns 1 if the user clicked
-- on a hyperText link, 2 if the user clicked on a hyperMedia
-- link, and -1 if the user did not click on a hyper link.

on getHyperLinkType wordNumber
  -- note: must check for hypermedia link before hypertext link
  -- because both are bold and hypermedia link also has a color
  -- conditon. if hypertext check was done first, hypermedia links
  -- would be processed as hypertext.
  if isHyperMediaLink(wordNumber) then
    return 2
  else if isHyperTextLink(wordNumber) then
    return 1
  else
    return -1
  end if
end

-- --------------------------------------------------------
-- Handler processHyperLink processes the hyperlink.

on processHyperLink wordNumber, linkType
  set hyperLinkWords = getHyperLinkWords(wordNumber)
  hiliteHyperLinkwords(hyperLinkWords)
  goHyperLink(hyperLinkWords, linkType)
end

-- --------------------------------------------------------
-- Handler isHyperTextLink returns TRUE if the given wordNumber of
-- the given field is a hypertext link (defined by bold)
-- and returns FALSE otherwise.

on isHyperTextLink wordNumber
  global currentTextCast

  if (length(word wordNumber of field currentTextCast) > 1) then
    set wordStyle = the textStyle of char 2 of word wordNumber of field currentTextCast
  else
    set wordStyle = the textStyle of word wordNumber of field currentTextCast
  end if

  if (wordStyle contains "bold") then
    return TRUE
  else
    return FALSE
  end if
end

-- --------------------------------------------------------
-- Handler isHyperMediaLink returns TRUE if the given wordNumber of
-- the given field is a hypermedia link (defined by bold and foreColor
-- of word clicked = hypermediaLinkColor) and returns FALSE otherwise.

on isHyperMediaLink wordNumber
  global currentTextCast, hyperMediaLinkColor

  if (length(word wordNumber of field currentTextCast) > 1) then
    set wordStyle = the textStyle of char 2 of word wordNumber of field currentTextCast
  else
    set wordStyle = the textStyle of word wordNumber of field currentTextCast
  end if

  set wordColor = the foreColor of word wordNumber of field currentTextCast

  return (wordStyle contains "bold") and (wordColor = hyperMediaLinkColor)
end

-- --------------------------------------------------------
-- Handler goHyperLink calls the proper go hyperlink handler.

on goHyperLink hyperLinkWords, linkType

  if (linkType = 1) then -- hypertext
    goHyperTextLink(hyperLinkWords)
  else if (linkType = 2) then -- hypermedia
    goHyperediaLink(hyperLinkWords)
  end if
end

-- --------------------------------------------------------
-- Handler goHyperTextLink puts the hypertext link of the
-- given word on stage

on goHyperTextLink hypertextWords
  global clickedTopic, hypertextPhrase

  set hypertextPhrase = getHypertextPhrase(hypertextWords)

  set clickedTopic = hypertextPhrase

  if (the number of cast (clickedTopic && "TEXT1") = -1) then
    set clickedTopic = getEquivalentTerm(clickedTopic)
  end if

  resetCurrentPage
  resetCurrentPicture
  resetCurrentCaption

  showSelectedTopic
end

-- --------------------------------------------------------
-- Handler goHyperMediaLink puts the hypermedia link of the
-- given word on stage

on goHyperediaLink hypertextWords
  global clickedTopic,hypertextPhrase

  set hypertextPhrase = getHypertextPhrase(hypertextWords)
  set clickedTopic = hypertextPhrase

  if (the number of cast (clickedTopic && "TEXT1") = -1) then
    set clickedTopic = getEquivalentTerm(clickedTopic)
  end if

  resetCurrentPage
  resetCurrentPicture
  resetCurrentCaption

  showSelectedMedia
end

-- --------------------------------------------------------
-- Handler getHyperLinkWords returns a list of the word
-- numbers in the hypertext link that were clicked on.

on getHyperLinkWords wordNumber
  global currentTextCast

  -- keep the list sorted
  set hyperLinkWords = [wordNumber]
  sort hyperLinkWords

  set linkStyle = the textStyle of word wordNumber of field currentTextCast
  set linkColor = the foreColor of word wordNumber of field currentTextCast

  -- get all the words before the clickedWord that are part
  -- of the hyperLink phrase.
  repeat with i = (wordNumber - 1) down to 1
    set theWord = word i of field currentTextCast
    if (the textStyle of word i of field currentTextCast = linkStyle) and (the foreColor of word i of field currentTextCast = linkColor) and not(endsWithPunctuation(theWord)) then
      add(hyperLinkWords, i)
    else -- reached the beginning of the phrase
      exit repeat
    end if
  end repeat

  -- If the clickedWord does not end with punctuation,
  -- get all the words after the clickedWord that are part
  -- of the hypertext phrase.
  if not(endsWithPunctuation(word wordNumber of field currentTextCast)) then
    repeat with i = (wordNumber + 1) to the number of words in field currentTextCast
      if (the textStyle of word i of field currentTextCast = linkStyle) and (the foreColor of word i of field currentTextCast = linkColor) then
        add(hyperLinkWords, i)
        if endsWithPunctuation(word i of field currentTextCast) then
          exit repeat
        end if
      else -- reached the end of the phrase
        exit repeat
      end if
    end repeat
  end if

  return hyperLinkWords
end

-- --------------------------------------------------------
-- Handler hiliteHyperLinkwords hilites the hyperLink words
-- of the clicked on phrase.

on hiliteHyperLinkwords hypertextWords
  global currentTextCast, hilitBackground, hypertextHiliteColor

  set numHypertextwords = count(hypertextWords)
  set firstword = getAt(hypertextWords, 1)
  set lastword = firstword + numHypertextwords - 1

  set oldForeColor = the foreColor of word firstWord of field currentTextCast
  set the foreColor of word firstword to lastword of field currentTextCast = hypertextHiliteColor

  updateStage

  set the foreColor of word firstword to lastword of field currentTextCast = oldForeColor
end

-- --------------------------------------------------------
-- Handler getHypertextPhrase returns the hypertext phrase
-- that was clicked.

on getHypertextPhrase hypertextWords
  global currentTextCast

  set numHypertextwords = count(hypertextWords)
  set firstword = getAt(hypertextWords, 1)
  set lastword = firstword + numHypertextwords - 1

  set hypertextPhrase = word firstword to lastword of field currentTextCast

  repeat while endsWithPunctuation(hypertextPhrase)
    set hypertextPhrase = removePunctuationFromEnd(hypertextPhrase)
  end repeat

  return hypertextPhrase
end

-- --------------------------------------------------------
-- Handler showSelectedMedia is called when the user clicks
-- on a hyperMedia link. It DOES WHAT?

on showSelectedMedia
  alert "you clicked on a hypermedia link"
end